string ColHilites[50]
integer MaxColHiliteX
//...
proc ClearAllColHilites()
    ColHilites=Format("":50:Chr(0))
    UpdateDisplay(_WINDOW_REFRESH_)
end
proc SetMaxColHiliteX()
    integer i,xx

    MaxColHiliteX=0
    for i=0 to 24
        xx=Asc(ColHilites[i*2+1])+256*Asc(ColHilites[i*2+2])
        if MaxColHiliteX<xx MaxColHiliteX=xx endif
    endfor
end
proc ToggleHiLiteCurrCol()
    integer i,x,xx

    if NumWindows()==1
        x=CurrCol()
        for i=0 to 24
            xx=Asc(ColHilites[i*2+1])+256*Asc(ColHilites[i*2+2])
            if x==xx
                ColHilites[i*2+1]=Chr(0)
                ColHilites[i*2+2]=Chr(0)
                UpdateDisplay(_WINDOW_REFRESH_)
                SetMaxColHiliteX()
                return()
            endif
        endfor
        for i=0 to 24
            xx=Asc(ColHilites[i*2+1])+256*Asc(ColHilites[i*2+2])
            if xx==0
                ColHilites[i*2+1]=Chr(x mod 256)
                ColHilites[i*2+2]=Chr(x/256)
                SetMaxColHiliteX()
                return()
            endif
        endfor
    endif
end
integer proc WidthOfShowLineNumbers()
    integer wsln,nls=NumLines()
    wsln=Length(Str(nls))
    if wsln<4
        wsln=4
    elseif nls<10000
        wsln=4
    elseif 10000<=nls and nls<1000000
        wsln=wsln+1 //one comma
    elseif 1000000<=nls and nls<1000000000
        wsln=wsln+2 //two comma
    else
        wsln=wsln+3 //three comma
    endif
    return(wsln+1)
end
proc OnAfterUpdateDisplay()
    integer i,x,from_where,c,w
    integer xx,yy,att,ln,ye
    string s[1]=" ",a[1]=" "

    ln=0
    if Query(ShowLineNumbers)
        ln=WidthOfShowLineNumbers()
    endif
    if NumWindows()==1 and ColHilites<>Format("":50:Chr(0))
        for i=0 to 24
            x=Asc(ColHilites[i*2+1])+256*Asc(ColHilites[i*2+2])
            if x>0
                xx=x-CurrXoffset()
                if 1<=xx and xx<=Query(WindowCols)
                    ye=Query(WindowRows)
                    yy=1
                    while yy<=ye
                        VGotoXY(xx+ln,yy)
                        GetStrAttr(s,a,1)
                        att=iif(Asc(a)==0x47,0x47,(Asc(a)&0x0F|iif((Asc(a)&0xF0)==0x20 or (Asc(a)&0xF0)==0x60,0x60,0x30)))
                        PutAttr(att,1)
                        yy = yy + 1
                    endwhile
                endif
            endif
        endfor
    endif
end
proc WhenLoaded()
    //...
    ColHilites=Format("":50:Chr(0))
    Hook(_AFTER_UPDATEDISPLAY_    , OnAfterUpdateDisplay)
    //...
end
//...
<CtrlShift \>           ToggleHiLiteCurrCol()
<CtrlShift u>           ClearAllColHilites()